Volumetric lightcones

[Higor]

A lil informative game.
Guess and tell me how you think I made it, and I'll post the code/test package

[Shadow]

You're letting some sprite actors to be rendered on a line, like 32 sprites for each cone

[Higor]

You're letting some sprite actors to be rendered on a line, like 32 sprites for each cone

Exactly.
I had a few inconvenients calibrating the distances and 2D 'expansion' the sprites had, giving a weird cone.
But it worked after a few arbitrary adjustments (no theoretics at all, but worked).

The sprites are created in runtime except for the master sprite.
The master sprite holds the normalized direction the new sprites should go, as well as the amount of child sprites, and target size/darken should be.
The child sprites inherit the master sprite's texture and style... but with some nice randomized hardcoded water/ice textures, a nice fog effect inside the cones can be simulated.

Code: Select all

//=============================================================================
// FV_ConeMaker.
//=============================================================================
class FV_ConeMaker expands Decoration;

var() int Cones;
var() float FinalMult; //Final Scale multiplier (glow divisor)
var() vector Dir; //Normal of dir to spawn shit
var() float TotalDist;
var float FinalGScale;
var float FinalDScale;

simulated event PostBeginPlay()
{
	local int i;
	local float alpha, fFactor, fCur;
	local FV_ModuParticle curM;

	if ( Level.NetMode == NM_DedicatedServer )
		return;

	FinalDScale = DrawScale * FinalMult;
	FinalGScale = (ScaleGlow / FinalMult);
	FinalGScale = ((FinalGScale * 3 + ScaleGlow) / 4) - FinalGScale; //Preserve some light scale
	Dir = Normal(Dir);

	fFactor = (1.3 ** (1+FinalMult) ) - 1.3;
	While ( i<Cones )
	{
		i++;
		alpha = ((1.3 ** (1+(FinalMult * i / Cones))) - 1.3 ) / fFactor;
		curM = Spawn( class'FV_ModuParticle',,, Location + Dir * TotalDist * Alpha);
		curM.DrawScale = DrawScale + (FinalDScale - DrawScale) * Alpha;
		curM.ScaleGlow = ScaleGlow + (FinalGScale - ScaleGlow) * Alpha;
		curM.Style = Style;
		curM.bUnlit = bUnlit;
		curM.AmbientGlow = AmbientGlow;
		curM.Texture = Texture;
	}
}

On the formula determining the interpolation points between 0 and 1 (alpha), instead of doing it in a linear fashion I had to employ an exponent on (1.3 ^ (the actual alpha) - 1.3) (1.4 works too, it's the SQRT(2) after all), that is because the sprites are square and would make the cone look very weird otherwise.

EDIT:
Base values for the screenshot:
Texture = Texture'XFX.inoxxy'
Style = STY_Translucent
DrawScale = 0.300000
ScaleGlow = 0.200000
bUnlit = False (should be true... well)
Cones = 15
Dir = (Z=-1) and (Z=1)
FinalMult = 5.000000
TotalDist = 600.000000

[papercoffee]

How to use this beauty ???

[Higor]

Well, ideally you should really embed this into maps in order to allow better customization and networking (1 less package).
Which is how I actually did it.

If somebody had some nice ICE/WATER textures with some distortion on them, a very cool fog effect might come out of it.
I'll have a U package tomorrow...

Some more eye candy:

[Higor]

Opps, I forgot about the particle class:

Code: Select all

class FV_ModuParticle expands Effects;

defaultproperties
{
    DrawType=DT_Sprite
}

There, subclassing effects sets automatically RemoteRole to ROLE_None.

[Creavion]

Too sad, nice stuff like this "always" comes too late.