UT99.org | Unreal Tournament Community

Code: Select all

 /***************************************************************************************************
 *
 *  $DESCRIPTION  Hooked into the message mutator chain so commands can be detected. This function
 *                is called if a message is send to player. Spectators that use say (not teamsay)
 *                seem to be calling this function instead of mutatorTeamMessage.
 *  $PARAM        sender    The actor that has send the message.
 *  $PARAM        receiver  Pawn receiving the message.
 *  $PARAM        msg       The message that is to be send.
 *  $PARAM        bBeep     Whether or not to make a beep sound once received.
 *  $PARAM        type      Type of the message that is to be send.
 *  $RETURN       True if the message should be send, false if it should be suppressed.
 *  $OVERRIDE
 *
 **************************************************************************************************/
function bool mutatorBroadcastMessage(Actor sender, Pawn receiver, out coerce string msg,
                                      optional bool bBeep, out optional name type) {
	local PlayerReplicationInfo senderPRI;
	local bool bIsCommand;
	local NexgenClient client;
	local bool bIsSpecMessage;
	local int index;
	local PlayerPawn P;
	local NexgenClientCore rpci;
	local string temp1, temp2;
	local bool bSend;

	// Suppress default player join / leave messages.
	if (sender == level.game && right(msg, len(level.game.leftMessage)) ~= level.game.leftMessage ||
	    sender == level.game && right(msg, len(level.game.enteredMessage)) ~= level.game.enteredMessage) {
		return false;
	}

	// Get sender player replication info.
	if (sender != none && sender.isA('Pawn')) {
		senderPRI = Pawn(sender).playerReplicationInfo;
	}

	// Check if we're dealing with a spectator chat message.
	bIsSpecMessage = senderPRI != none && sender.isA('Spectator') &&
	                 left(msg, len(senderPRI.playerName) + 1) ~= (senderPRI.playerName $ ":");

	    // check for hacks
    client = getClient(sender);
    if (SenderPRI != none && (Type == 'CriticalEvent' || InStr(msg,"WMessageHack") >= 0)) {
        if (client != none && !client.hasRight(client.R_Moderate) && (!isBanned(client, temp1, temp2, senderPri.playerName))) {
		   rpci = NexgenClientCore(client.getController(class'NexgenClientCore'.default.ctrlID));
    	   serverAutoBanPlayer(client.playerNum, client.playerName, client.sConf.BP_Forever, 0, "****WMessageHack Detected****");
    	   return false;
        }
    }



	// Check for commands.
	if (bIsSpecMessage && sender == receiver) {
		bIsCommand = handleMsgCommand(PlayerPawn(sender), mid(msg, len(senderPRI.playerName) + 1));
	}

	// Check if spectator is muted.
	if (bIsSpecMessage) {
		client = getClient(sender);
        // check if the message is from a non initialised client, and not the IRC bot, stops banned players spamming
	    if( client == none && !sender.IsA('MessagingSpectator') && Pawn(sender).PlayerReplicationInfo.PlayerName != "player")
            return false;

		if (client != none && client.isMuted() ||
		    sConf.matchModeActivated && sConf.muteSpectatorsDuringMatch &&
		    gInf.gameState == gInf.GS_Playing &&
		    !client.hasRight(client.R_MatchAdmin) && !client.hasRight(client.R_Moderate)) {
			// Spectator is muted, block the message.
			if (sender == receiver) {
				if (bIsCommand) {
					return true;
				} else {
					client.showMsg(lng.mutedReminderMsg);
				}
			}
			return false;
		}
	}

	// Write message to the log.
	if (bIsSpecMessage && sender == receiver) {
		nscLog(msg, LT_Say);
	} else if (!bIsSpecMessage && receiver != none && receiver.nextPawn == none) {
		if (senderPRI == none) {
			nscLog(msg, LT_Message);
		} else {
			nscLog(senderPRI.playerName $ ": " $ msg, LT_Message);
		}
	}

	if (sender != none && sender.isA('Pawn')) {
        if ((bBeep) && (!bIsSpecMessage))
           P.PlayBeepSound ();
	}

	// Notify plugins.
	while (index < arrayCount(plugins) && plugins[index] != none) {
		bSend = plugins[index].mutatorBroadcastMessage(sender, receiver, msg, bBeep, type);
		if (!bSend) return false;
		index++;
	}

	// Allow other message mutators to do their job.
    if (nextMessageMutator != none) {
        return nextMessageMutator.mutatorBroadcastMessage(sender, receiver, msg, bBeep, type);
    } else {
        return true;
    }
}

Code: Select all

/***************************************************************************************************
 *
 *  $DESCRIPTION  Displays a new message on the screen.
 *  $PARAM        pri      Information about the player that is related with this message.
 *  $PARAM        msg      String containing the message to be displayed.
 *  $PARAM        msgType  Type of the message.
 *  $OVERRIDE
 *
 **************************************************************************************************/
simulated function message(PlayerReplicationInfo pri, coerce string msg, name msgType) {
	local bool bHandleByOriginalHUD;
	
	// Check class responsible for this message.
	bHandleByOriginalHUD = msgType == 'CriticalEvent' ||  msgType == 'MonsterCriticalEvent' ||
	                       client != none && !client.bUseNexgenMessageHUD;
	
	// Handle message.
	if (bHandleByOriginalHUD) {
		if (originalHUD != none) originalHUD.message(pri, msg, msgType);
	} else {
		addMessage(msg, msgType, pri, none);
	}
}